Added vim configuration files to repository.

vim/.vim/.netrwhist

+let g:netrw_dirhistmax  =10
+let g:netrw_dirhist_cnt =4
+let g:netrw_dirhist_1='/home/sander/Desktop/bapc-2009'
+let g:netrw_dirhist_2='/home/sander/Desktop/bapc-2009/preliminary'
+let g:netrw_dirhist_3='/home/sander/Programming/web/vo20/cache'
+let g:netrw_dirhist_4='/home/sander/.vim'

vim/.vim/after/ftplugin/c.vim

+" OmniCppComplete initialization
+call omni#cpp#complete#Init()

vim/.vim/after/ftplugin/cpp.vim

+" OmniCppComplete initialization
+call omni#cpp#complete#Init()

vim/.vim/autoload/omni/common/debug.vim

+" Description: Omni completion debug functions
+" Maintainer:  Vissale NEANG
+" Last Change: 26 sept. 2007
+
+let s:CACHE_DEBUG_TRACE = []
+
+" Start debug, clear the debug file
+function! omni#common#debug#Start()
+    let s:CACHE_DEBUG_TRACE = []
+    call extend(s:CACHE_DEBUG_TRACE, ['============ Debug Start ============'])
+    call writefile(s:CACHE_DEBUG_TRACE, "Omni.dbg")
+endfunc
+
+" End debug, write to debug file
+function! omni#common#debug#End()
+    call extend(s:CACHE_DEBUG_TRACE, ["============= Debug End ============="])
+    call extend(s:CACHE_DEBUG_TRACE, [""])
+    call writefile(s:CACHE_DEBUG_TRACE, "Omni.dbg")
+endfunc
+
+" Debug trace function
+function! omni#common#debug#Trace(szFuncName, ...)
+    let szTrace = a:szFuncName
+    let paramNum = a:0
+    if paramNum>0
+        let szTrace .= ':'
+    endif
+    for i in range(paramNum)
+        let szTrace = szTrace .' ('. string(eval('a:'.string(i+1))).')'
+    endfor
+    call extend(s:CACHE_DEBUG_TRACE, [szTrace])
+endfunc

vim/.vim/autoload/omni/common/utils.vim

+" Description: Omni completion utils
+" Maintainer:  Vissale NEANG
+" Last Change: 26 sept. 2007
+
+" For sort numbers in list
+function! omni#common#utils#CompareNumber(i1, i2)
+    let num1 = eval(a:i1)
+    let num2 = eval(a:i2)
+    return num1 == num2 ? 0 : num1 > num2 ? 1 : -1
+endfunc
+
+" TagList function calling the vim taglist() with try catch
+" The only throwed exception is 'TagList:UserInterrupt'
+" We also force the noignorecase option to avoid linear search when calling
+" taglist()
+function! omni#common#utils#TagList(szTagQuery)
+    let result = []
+    let bUserIgnoreCase = &ignorecase
+    " Forcing noignorecase search => binary search can be used in taglist()
+    " if tags in the tag file are sorted
+    if bUserIgnoreCase
+        set noignorecase
+    endif
+    try
+        let result = taglist(a:szTagQuery)
+    catch /^Vim:Interrupt$/
+        " Restoring user's setting
+        if bUserIgnoreCase
+            set ignorecase
+        endif
+        throw 'TagList:UserInterrupt'
+    catch
+        "Note: it seems that ctags can generate corrupted files, in this case
+        "taglist() will fail to read the tagfile and an exception from
+        "has_add() is thrown
+    endtry
+
+    " Restoring user's setting
+    if bUserIgnoreCase
+        set ignorecase
+    endif
+    return result
+endfunc
+
+" Same as TagList but don't throw exception
+function! omni#common#utils#TagListNoThrow(szTagQuery)
+    let result = []
+    try
+        let result = omni#common#utils#TagList(a:szTagQuery)
+    catch
+    endtry
+    return result
+endfunc
+
+" Get the word under the cursor
+function! omni#common#utils#GetWordUnderCursor()
+    let szLine = getline('.')
+    let startPos = getpos('.')[2]-1
+    let startPos = (startPos < 0)? 0 : startPos
+    if szLine[startPos] =~ '\w'
+        let startPos = searchpos('\<\w\+', 'cbn', line('.'))[1] - 1
+    endif
+
+    let startPos = (startPos < 0)? 0 : startPos
+    let szResult = matchstr(szLine, '\w\+', startPos)
+    return szResult
+endfunc

vim/.vim/autoload/omni/cpp/includes.vim

+" Description: Omni completion script for cpp files
+" Maintainer:  Vissale NEANG
+" Last Change: 26 sept. 2007
+
+let g:omni#cpp#includes#CACHE_INCLUDES = {}
+let g:omni#cpp#includes#CACHE_FILE_TIME = {}
+
+let s:rePreprocIncludePart = '\C#\s*include\s*'
+let s:reIncludeFilePart = '\(<\|"\)\(\f\|\s\)\+\(>\|"\)'
+let s:rePreprocIncludeFile = s:rePreprocIncludePart . s:reIncludeFilePart
+
+" Get the include list of a file
+function! omni#cpp#includes#GetList(...)
+    if a:0 > 0
+        return s:GetIncludeListFromFile(a:1, (a:0 > 1)? a:2 : 0 )
+    else
+        return s:GetIncludeListFromCurrentBuffer()
+    endif
+endfunc
+
+" Get the include list from the current buffer
+function! s:GetIncludeListFromCurrentBuffer()
+    let listIncludes = []
+    let originalPos = getpos('.')
+
+    call setpos('.', [0, 1, 1, 0])
+    let curPos = [1,1]
+    let alreadyInclude = {}
+    while curPos != [0,0]
+        let curPos = searchpos('\C\(^'.s:rePreprocIncludeFile.'\)', 'W')
+        if curPos != [0,0]
+            let szLine = getline('.')
+            let startPos = curPos[1]
+            let endPos = matchend(szLine, s:reIncludeFilePart, startPos-1)
+            if endPos!=-1
+                let szInclusion = szLine[startPos-1:endPos-1]
+                let szIncludeFile = substitute(szInclusion, '\('.s:rePreprocIncludePart.'\)\|[<>""]', '', 'g')
+                let szResolvedInclude = omni#cpp#utils#ResolveFilePath(szIncludeFile)
+
+                " Protection over self inclusion
+                if szResolvedInclude != '' && szResolvedInclude != omni#cpp#utils#ResolveFilePath(getreg('%'))
+                    let includePos = curPos
+                    if !has_key(alreadyInclude, szResolvedInclude)
+                        call extend(listIncludes, [{'pos' : includePos, 'include' : szResolvedInclude}])
+                        let alreadyInclude[szResolvedInclude] = 1
+                    endif
+                endif
+            endif
+        endif
+    endwhile
+
+    call setpos('.', originalPos)
+    return listIncludes
+endfunc
+
+" Get the include list from a file
+function! s:GetIncludeListFromFile(szFilePath, bUpdate) 
+    let listIncludes = []
+    if a:szFilePath == ''
+        return listIncludes
+    endif
+
+    if !a:bUpdate && has_key(g:omni#cpp#includes#CACHE_INCLUDES, a:szFilePath)
+        return copy(g:omni#cpp#includes#CACHE_INCLUDES[a:szFilePath])
+    endif
+
+    let g:omni#cpp#includes#CACHE_FILE_TIME[a:szFilePath] = getftime(a:szFilePath)
+
+    let szFixedPath = escape(a:szFilePath, g:omni#cpp#utils#szEscapedCharacters)
+    execute 'silent! lvimgrep /\C\(^'.s:rePreprocIncludeFile.'\)/gj '.szFixedPath
+
+    let listQuickFix = getloclist(0)
+    let alreadyInclude = {}
+    for qf in listQuickFix
+        let szLine = qf.text
+        let startPos = qf.col
+        let endPos = matchend(szLine, s:reIncludeFilePart, startPos-1)
+        if endPos!=-1
+            let szInclusion = szLine[startPos-1:endPos-1]
+            let szIncludeFile = substitute(szInclusion, '\('.s:rePreprocIncludePart.'\)\|[<>""]', '', 'g')
+            let szResolvedInclude = omni#cpp#utils#ResolveFilePath(szIncludeFile)
+            
+            " Protection over self inclusion
+            if szResolvedInclude != '' && szResolvedInclude != a:szFilePath
+                let includePos = [qf.lnum, qf.col]
+                if !has_key(alreadyInclude, szResolvedInclude)
+                    call extend(listIncludes, [{'pos' : includePos, 'include' : szResolvedInclude}])
+                    let alreadyInclude[szResolvedInclude] = 1
+                endif
+            endif
+        endif
+    endfor
+
+    let g:omni#cpp#includes#CACHE_INCLUDES[a:szFilePath] = listIncludes
+
+    return copy(listIncludes)
+endfunc
+
+" For debug purpose
+function! omni#cpp#includes#Display()
+    let szPathBuffer = omni#cpp#utils#ResolveFilePath(getreg('%'))
+    call s:DisplayIncludeTree(szPathBuffer, 0)
+endfunc
+
+" For debug purpose
+function! s:DisplayIncludeTree(szFilePath, indent, ...)
+    let includeGuard = {}
+    if a:0 >0
+        let includeGuard = a:1
+    endif
+    let szFilePath = omni#cpp#utils#ResolveFilePath(a:szFilePath)
+    if has_key(includeGuard, szFilePath)
+        return
+    else
+        let includeGuard[szFilePath] = 1
+    endif
+
+    let szIndent = repeat('    ', a:indent)
+    echo szIndent . a:szFilePath
+    let incList = omni#cpp#includes#GetList(a:szFilePath)
+    for inc in incList
+        call s:DisplayIncludeTree(inc.include, a:indent+1, includeGuard)
+    endfor
+endfunc
+
+

vim/.vim/autoload/omni/cpp/maycomplete.vim

+" Description: Omni completion script for cpp files
+" Maintainer:  Vissale NEANG
+" Last Change: 26 sept. 2007
+
+" Check if we can use omni completion in the current buffer
+function! s:CanUseOmnicompletion()
+    " For C and C++ files and only if the omnifunc is omni#cpp#complete#Main
+    return (index(['c', 'cpp'], &filetype)>=0 && &omnifunc == 'omni#cpp#complete#Main' && !omni#cpp#utils#IsCursorInCommentOrString())
+endfunc
+
+" Return the mapping of omni completion
+function! omni#cpp#maycomplete#Complete()
+    let szOmniMapping = "\<C-X>\<C-O>"
+
+    "   0 = don't select first item
+    "   1 = select first item (inserting it to the text, default vim behaviour)
+    "   2 = select first item (without inserting it to the text)
+    if g:OmniCpp_SelectFirstItem == 0
+        " We have to force the menuone option to avoid confusion when there is
+        " only one popup item
+        set completeopt-=menu
+        set completeopt+=menuone
+        let szOmniMapping .= "\<C-P>"
+    elseif g:OmniCpp_SelectFirstItem == 2
+        " We have to force the menuone option to avoid confusion when there is
+        " only one popup item
+        set completeopt-=menu
+        set completeopt+=menuone
+        let szOmniMapping .= "\<C-P>"
+        let szOmniMapping .= "\<C-R>=pumvisible() ? \"\\<down>\" : \"\"\<cr>"
+    endif
+    return szOmniMapping
+endfunc
+
+" May complete function for dot
+function! omni#cpp#maycomplete#Dot()
+    if s:CanUseOmnicompletion() && g:OmniCpp_MayCompleteDot
+        let g:omni#cpp#items#data = omni#cpp#items#Get(omni#cpp#utils#TokenizeCurrentInstruction('.'))
+        if len(g:omni#cpp#items#data)
+            let s:bMayComplete = 1
+            return '.' . omni#cpp#maycomplete#Complete()
+        endif
+    endif
+    return '.'
+endfunc
+" May complete function for arrow
+function! omni#cpp#maycomplete#Arrow()
+    if s:CanUseOmnicompletion() && g:OmniCpp_MayCompleteArrow
+        let index = col('.') - 2
+        if index >= 0
+            let char = getline('.')[index]
+            if char == '-'
+                let g:omni#cpp#items#data = omni#cpp#items#Get(omni#cpp#utils#TokenizeCurrentInstruction('>'))
+                if len(g:omni#cpp#items#data)
+                    let s:bMayComplete = 1
+                    return '>' . omni#cpp#maycomplete#Complete()
+                endif
+            endif
+        endif
+    endif
+    return '>'
+endfunc
+
+" May complete function for double points
+function! omni#cpp#maycomplete#Scope()
+    if s:CanUseOmnicompletion() && g:OmniCpp_MayCompleteScope
+        let index = col('.') - 2
+        if index >= 0
+            let char = getline('.')[index]
+            if char == ':'
+                let g:omni#cpp#items#data = omni#cpp#items#Get(omni#cpp#utils#TokenizeCurrentInstruction(':'))
+                if len(g:omni#cpp#items#data)
+                    if len(g:omni#cpp#items#data[-1].tokens) && g:omni#cpp#items#data[-1].tokens[-1].value != '::'
+                        let s:bMayComplete = 1
+                        return ':' . omni#cpp#maycomplete#Complete()
+                    endif
+                endif
+            endif
+        endif
+    endif
+    return ':'
+endfunc

vim/.vim/autoload/omni/cpp/settings.vim

+" Description: Omni completion script for cpp files
+" Maintainer:  Vissale NEANG
+" Last Change: 26 sept. 2007
+
+function! omni#cpp#settings#Init()
+    " Global scope search on/off
+    "   0 = disabled
+    "   1 = enabled
+    if !exists('g:OmniCpp_GlobalScopeSearch') 
+        let g:OmniCpp_GlobalScopeSearch = 1
+    endif
+
+    " Sets the namespace search method
+    "   0 = disabled
+    "   1 = search namespaces in the current file
+    "   2 = search namespaces in the current file and included files
+    if !exists('g:OmniCpp_NamespaceSearch') 
+        let g:OmniCpp_NamespaceSearch = 1
+    endif
+
+    " Set the class scope completion mode
+    "   0 = auto
+    "   1 = show all members (static, public, protected and private)
+    if !exists('g:OmniCpp_DisplayMode') 
+        let g:OmniCpp_DisplayMode = 0
+    endif
+
+    " Set if the scope is displayed in the abbr column of the popup
+    "   0 = no
+    "   1 = yes
+    if !exists('g:OmniCpp_ShowScopeInAbbr') 
+        let g:OmniCpp_ShowScopeInAbbr = 0
+    endif
+
+    " Set if the function prototype is displayed in the abbr column of the popup
+    "   0 = no
+    "   1 = yes
+    if !exists('g:OmniCpp_ShowPrototypeInAbbr') 
+        let g:OmniCpp_ShowPrototypeInAbbr = 0
+    endif
+    
+    " Set if the access (+,#,-) is displayed
+    "   0 = no
+    "   1 = yes
+    if !exists('g:OmniCpp_ShowAccess') 
+        let g:OmniCpp_ShowAccess = 1
+    endif
+
+    " Set the list of default namespaces
+    " eg: ['std']
+    if !exists('g:OmniCpp_DefaultNamespaces') 
+        let g:OmniCpp_DefaultNamespaces = []
+    endif
+
+    " Set MayComplete to '.'
+    "   0 = disabled
+    "   1 = enabled
+    "   default = 1
+    if !exists('g:OmniCpp_MayCompleteDot') 
+        let g:OmniCpp_MayCompleteDot = 1
+    endif
+
+    " Set MayComplete to '->'
+    "   0 = disabled
+    "   1 = enabled
+    "   default = 1
+    if !exists('g:OmniCpp_MayCompleteArrow') 
+        let g:OmniCpp_MayCompleteArrow = 1
+    endif
+
+    " Set MayComplete to dot
+    "   0 = disabled
+    "   1 = enabled
+    "   default = 0
+    if !exists('g:OmniCpp_MayCompleteScope') 
+        let g:OmniCpp_MayCompleteScope = 0
+    endif
+
+    " When completeopt does not contain longest option, this setting 
+    " controls the behaviour of the popup menu selection when starting the completion
+    "   0 = don't select first item
+    "   1 = select first item (inserting it to the text)
+    "   2 = select first item (without inserting it to the text)
+    "   default = 0
+    if !exists('g:OmniCpp_SelectFirstItem') 
+        let g:OmniCpp_SelectFirstItem= 0
+    endif
+
+    " Use local search function for variable definitions
+    "   0 = use standard vim search function
+    "   1 = use local search function
+    "   default = 0
+    if !exists('g:OmniCpp_LocalSearchDecl') 
+        let g:OmniCpp_LocalSearchDecl= 0
+    endif
+endfunc

vim/.vim/autoload/omni/cpp/tokenizer.vim

+" Description: Omni completion tokenizer
+" Maintainer:  Vissale NEANG
+" Last Change: 26 sept. 2007
+" TODO: Generic behaviour for Tokenize()
+
+" From the C++ BNF
+let s:cppKeyword = ['asm', 'auto', 'bool', 'break', 'case', 'catch', 'char', 'class', 'const', 'const_cast', 'continue', 'default', 'delete', 'do', 'double', 'dynamic_cast', 'else', 'enum', 'explicit', 'export', 'extern', 'false', 'float', 'for', 'friend', 'goto', 'if', 'inline', 'int', 'long', 'mutable', 'namespace', 'new', 'operator', 'private', 'protected', 'public', 'register', 'reinterpret_cast', 'return', 'short', 'signed', 'sizeof', 'static', 'static_cast', 'struct', 'switch', 'template', 'this', 'throw', 'true', 'try', 'typedef', 'typeid', 'typename', 'union', 'unsigned', 'using', 'virtual', 'void', 'volatile', 'wchar_t', 'while', 'and', 'and_eq', 'bitand', 'bitor', 'compl', 'not', 'not_eq', 'or', 'or_eq', 'xor', 'xor_eq']
+
+let s:reCppKeyword = '\C\<'.join(s:cppKeyword, '\>\|\<').'\>'
+
+" The order of items in this list is very important because we use this list to build a regular
+" expression (see below) for tokenization
+let s:cppOperatorPunctuator = ['->*', '->', '--', '-=', '-', '!=', '!', '##', '#', '%:%:', '%=', '%>', '%:', '%', '&&', '&=', '&', '(', ')', '*=', '*', ',', '...', '.*', '.', '/=', '/', '::', ':>', ':', ';', '?', '[', ']', '^=', '^', '{', '||', '|=', '|', '}', '~', '++', '+=', '+', '<<=', '<%', '<:', '<<', '<=', '<', '==', '=', '>>=', '>>', '>=', '>']
+
+" We build the regexp for the tokenizer
+let s:reCComment = '\/\*\|\*\/'
+let s:reCppComment = '\/\/'
+let s:reComment = s:reCComment.'\|'.s:reCppComment
+let s:reCppOperatorOrPunctuator = escape(join(s:cppOperatorPunctuator, '\|'), '*./^~[]')
+
+
+" Tokenize a c++ code
+" a token is dictionary where keys are:
+"   -   kind = cppKeyword|cppWord|cppOperatorPunctuator|unknown|cComment|cppComment|cppDigit
+"   -   value = 'something'
+"   Note: a cppWord is any word that is not a cpp keyword
+function! omni#cpp#tokenizer#Tokenize(szCode)
+    let result = []
+
+    " The regexp to find a token, a token is a keyword, word or
+    " c++ operator or punctuator. To work properly we have to put 
+    " spaces and tabs to our regexp.
+    let reTokenSearch = '\(\w\+\)\|\s\+\|'.s:reComment.'\|'.s:reCppOperatorOrPunctuator
+    " eg: 'using namespace std;'
+    "      ^    ^
+    "  start=0 end=5
+    let startPos = 0
+    let endPos = matchend(a:szCode, reTokenSearch)
+    let len = endPos-startPos
+    while endPos!=-1
+        " eg: 'using namespace std;'
+        "      ^    ^
+        "  start=0 end=5
+        "  token = 'using'
+        " We also remove space and tabs
+        let token = substitute(strpart(a:szCode, startPos, len), '\s', '', 'g')
+
+        " eg: 'using namespace std;'
+        "           ^         ^
+        "       start=5     end=15
+        let startPos = endPos
+        let endPos = matchend(a:szCode, reTokenSearch, startPos)
+        let len = endPos-startPos
+
+        " It the token is empty we continue
+        if token==''
+            continue
+        endif
+
+        " Building the token
+        let resultToken = {'kind' : 'unknown', 'value' : token}
+
+        " Classify the token
+        if token =~ '^\d\+'
+            " It's a digit
+            let resultToken.kind = 'cppDigit'
+        elseif token=~'^\w\+$'
+            " It's a word
+            let resultToken.kind = 'cppWord'
+
+            " But maybe it's a c++ keyword
+            if match(token, s:reCppKeyword)>=0
+                let resultToken.kind = 'cppKeyword'
+            endif
+        else
+            if match(token, s:reComment)>=0
+                if index(['/*','*/'],token)>=0
+                    let resultToken.kind = 'cComment'
+                else
+                    let resultToken.kind = 'cppComment'
+                endif
+            else
+                " It's an operator
+                let resultToken.kind = 'cppOperatorPunctuator'
+            endif
+        endif
+
+        " We have our token, let's add it to the result list
+        call extend(result, [resultToken])
+    endwhile
+
+    return result
+endfunc

vim/.vim/colors/darkspectrum.vim

+" Vim color file
+"
+" Author: Brian Mock <mock.brian@gmail.com>
+"
+" Note: Based on Oblivion color scheme for gedit (gtk-source-view)
+"
+" cool help screens
+" :he group-name
+" :he highlight-groups
+" :he cterm-colors
+
+hi clear
+
+set background=dark
+if version > 580
+    " no guarantees for version 5.8 and below, but this makes it stop
+    " complaining
+    hi clear
+    if exists("syntax_on")
+	syntax reset
+    endif
+endif
+let g:colors_name="darkspectrum"
+
+hi Normal guifg=#efefef guibg=#2A2A2A
+
+" highlight groups
+hi Cursor		guibg=#ffffff guifg=#000000
+hi CursorLine	guibg=#000000
+"hi CursorLine	guibg=#3e4446
+hi CursorColumn	guibg=#464646
+
+"hi DiffText     guibg=#4e9a06 guifg=#FFFFFF gui=bold
+"hi DiffChange   guibg=#4e9a06 guifg=#FFFFFF gui=bold
+"hi DiffAdd      guibg=#204a87 guifg=#FFFFFF gui=bold
+"hi DiffDelete   guibg=#5c3566 guifg=#FFFFFF gui=bold
+
+hi DiffAdd         guifg=#ffcc7f guibg=#a67429 gui=none
+hi DiffChange      guifg=#7fbdff guibg=#425c78 gui=none
+hi DiffText        guifg=#8ae234 guibg=#4e9a06 gui=none
+"hi DiffDelete      guifg=#252723 guibg=#000000 gui=none
+hi DiffDelete      guifg=#000000 guibg=#000000 gui=none
+"hi ErrorMsg
+
+hi Number		guifg=#fce94f
+
+hi Folded		guibg=#000000 guifg=#FFFFFF gui=bold
+hi vimFold		guibg=#000000 guifg=#FFFFFF gui=bold
+hi FoldColumn	guibg=#000000 guifg=#FFFFFF gui=bold
+
+hi LineNr		guifg=#535353 guibg=#202020
+hi NonText		guifg=#535353 guibg=#202020
+hi Folded		guifg=#535353 guibg=#202020 gui=bold
+hi FoldeColumn  guifg=#535353 guibg=#202020 gui=bold
+"hi VertSplit	guibg=#ffffff guifg=#ffffff gui=none
+
+hi VertSplit	guibg=#3C3C3C guifg=#3C3C3C gui=none
+hi StatusLine   guifg=#FFFFFF guibg=#3C3C3C gui=none
+hi StatusLineNC guifg=#808080 guibg=#3C3C3C gui=none
+
+hi ModeMsg		guifg=#fce94f
+hi MoreMsg		guifg=#fce94f
+hi Visual		guifg=#FFFFFF guibg=#3465a4 gui=none
+hi VisualNOS    guifg=#FFFFFF guibg=#204a87 gui=none
+hi IncSearch	guibg=#FFFFFF guifg=#ef5939
+hi Search		guibg=#ad7fa8 guifg=#FFFFFF
+hi SpecialKey	guifg=#8ae234
+
+hi Title		guifg=#ef5939
+hi WarningMsg	guifg=#ef5939
+hi Number		guifg=#fcaf3e
+
+hi MatchParen	guibg=#ad7fa8 guifg=#FFFFFF
+hi Comment		guifg=#8a8a8a
+hi Constant		guifg=#ef5939 gui=none
+hi String		guifg=#fce94f
+hi Identifier	guifg=#729fcf
+hi Statement	guifg=#ffffff gui=bold
+hi PreProc		guifg=#ffffff gui=bold
+hi Type			guifg=#8ae234 gui=bold
+hi Special		guifg=#e9b96e
+hi Underlined	guifg=#ad7fa8 gui=underline
+hi Directory	guifg=#729fcf
+hi Ignore		guifg=#555753
+hi Todo			guifg=#FFFFFF guibg=#ef5939 gui=bold
+hi Function		guifg=#ad7fa8
+
+"hi WildMenu     guibg=#2e3436 guifg=#ffffff gui=bold
+"hi WildMenu     guifg=#7fbdff guibg=#425c78 gui=none
+hi WildMenu     guifg=#ffffff guibg=#3465a4 gui=none
+
+hi Pmenu        guibg=#000000 guifg=#c0c0c0
+hi PmenuSel     guibg=#3465a4 guifg=#ffffff
+hi PmenuSbar    guibg=#444444 guifg=#444444
+hi PmenuThumb   guibg=#888888 guifg=#888888 
+
+hi cppSTLType   guifg=#729fcf gui=bold
+
+hi spellBad     guisp=#fcaf3e
+hi spellCap     guisp=#73d216
+hi spellRare    guisp=#ad7fa8
+hi spellLocal   guisp=#729fcf
+
+hi link cppSTL          Function
+hi link Error			Todo
+hi link Character		Number
+hi link rubySymbol		Number
+hi link htmlTag			htmlEndTag
+"hi link htmlTagName     htmlTag
+hi link htmlLink		Underlined
+hi link pythonFunction	Identifier
+hi link Question		Type
+hi link CursorIM		Cursor
+hi link VisualNOS		Visual
+hi link xmlTag			Identifier
+hi link xmlTagName		Identifier
+hi link shDeref			Identifier
+hi link shVariable		Function
+hi link rubySharpBang	Special
+hi link perlSharpBang	Special
+hi link schemeFunc      Statement
+"hi link shSpecialVariables Constant
+"hi link bashSpecialVariables Constant
+
+" tabs (non gui)
+hi TabLine		guifg=#A3A3A3 guibg=#202020 gui=none
+hi TabLineFill	guifg=#535353 guibg=#202020 gui=none
+hi TabLineSel	guifg=#FFFFFF gui=bold
+"hi TabLineSel	guifg=#FFFFFF guibg=#000000 gui=bold
+" vim: sw=4 ts=4

vim/.vim/colors/wombat.vim

+" Maintainer:	Lars H. Nielsen (dengmao@gmail.com)
+" Last Change:	January 22 2007
+
+set background=dark
+
+hi clear
+
+if exists("syntax_on")
+  syntax reset
+endif
+
+let colors_name = "wombat"
+
+
+" Vim >= 7.0 specific colors
+if version >= 700
+  hi CursorLine guibg=#2d2d2d
+  hi CursorColumn guibg=#2d2d2d
+  hi MatchParen guifg=#f6f3e8 guibg=#857b6f gui=bold
+  hi Pmenu 		guifg=#f6f3e8 guibg=#444444
+  hi PmenuSel 	guifg=#000000 guibg=#cae682
+endif
+
+" General colors
+hi Cursor 		guifg=NONE    guibg=#656565 gui=none
+hi Normal 		guifg=#f6f3e8 guibg=#242424 gui=none
+hi NonText 		guifg=#808080 guibg=#303030 gui=none
+hi LineNr 		guifg=#857b6f guibg=#000000 gui=none
+hi StatusLine 	guifg=#f6f3e8 guibg=#444444 gui=italic
+hi StatusLineNC guifg=#857b6f guibg=#444444 gui=none
+hi VertSplit 	guifg=#444444 guibg=#444444 gui=none
+hi Folded 		guibg=#384048 guifg=#a0a8b0 gui=none
+hi Title		guifg=#f6f3e8 guibg=NONE	gui=bold
+hi Visual		guifg=#f6f3e8 guibg=#444444 gui=none
+hi SpecialKey	guifg=#808080 guibg=#343434 gui=none
+
+" Syntax highlighting
+hi Comment 		guifg=#99968b gui=italic
+hi Todo 		guifg=#8f8f8f gui=italic
+hi Constant 	guifg=#e5786d gui=none
+hi String 		guifg=#95e454 gui=italic
+hi Identifier 	guifg=#cae682 gui=none
+hi Function 	guifg=#cae682 gui=none
+hi Type 		guifg=#cae682 gui=none
+hi Statement 	guifg=#8ac6f2 gui=none
+hi Keyword		guifg=#8ac6f2 gui=none
+hi PreProc 		guifg=#e5786d gui=none
+hi Number		guifg=#e5786d gui=none
+hi Special		guifg=#e7f6da gui=none
+
+

vim/.vim/ftdetect/php.vim

+au BufRead,BufNewFile *.phpt set filetype=php
+au BufRead,BufNewFile Phakefile set filetype=php

vim/.vim/tags/qt4

+!_TAG_FILE_FORMAT	2	/extended format; --format=1 will not append ;" to lines/
+!_TAG_FILE_SORTED	1	/0=unsorted, 1=sorted, 2=foldcase/
+!_TAG_PROGRAM_AUTHOR	Darren Hiebert	/dhiebert@users.sourceforge.net/
+!_TAG_PROGRAM_NAME	Exuberant Ctags	//
+!_TAG_PROGRAM_URL	http://ctags.sourceforge.net	/official site/
+!_TAG_PROGRAM_VERSION	5.8	//

vim/.vim/tags/sdl

+!_TAG_FILE_FORMAT	2	/extended format; --format=1 will not append ;" to lines/
+!_TAG_FILE_SORTED	1	/0=unsorted, 1=sorted, 2=foldcase/
+!_TAG_PROGRAM_AUTHOR	Darren Hiebert	/dhiebert@users.sourceforge.net/
+!_TAG_PROGRAM_NAME	Exuberant Ctags	//
+!_TAG_PROGRAM_URL	http://ctags.sourceforge.net	/official site/
+!_TAG_PROGRAM_VERSION	5.8	//

vim/.vimrc

+set number
+set autoindent
+set incsearch
+set hlsearch
+set tabstop=4
+set ruler
+set shiftwidth=2
+
+set modeline
+
+" -- run in gnome-terminal: --
+" export TERM="xterm-256color"
+
+if $COLORTERM == 'gnome-terminal'
+	set t_Co=256
+endif
+
+"   ,rl = run pdflatex (on current file)
+map ,rl :!pdflatex -src -shell-escape -interaction=nonstopmode %
+
+" trigger pdflatex (above) on FileWritePost event
+:autocmd BufWritePost *.tex :!pdflatex -src -shell-escape -interaction=nonstopmode % | grep -A 4 -i "error" 
+
+set nocp
+filetype plugin on
+
+" configure tags - add additional tags here or comment out not-used ones
+set tags+=~/.vim/tags/stl
+set tags+=~/.vim/tags/gl
+
+" build tags of your own project with CTRL+F12
+"map <C-F12> :!ctags -R --c++-kinds=+p --fields=+iaS --extra=+q .<CR>
+"noremap <F12> :!ctags -R --c++-kinds=+p --fields=+iaS --extra=+q .<cr>
+"inoremap <F12> <Esc>:!ctags -R --c++-kinds=+p --fields=+iaS --extra=+q .<cr>
+
+" OmniCppComplete
+let OmniCpp_NamespaceSearch = 1
+let OmniCpp_GlobalScopeSearch = 1
+let OmniCpp_ShowAccess = 1
+let OmniCpp_MayCompleteDot = 1
+let OmniCpp_MayCompleteArrow = 1
+let OmniCpp_MayCompleteScope = 1
+let OmniCpp_DefaultNamespaces = ["std", "_GLIBCXX_STD"]
+
+" automatically open and close the popup menu / preview window
+au CursorMovedI,InsertLeave * if pumvisible() == 0|silent! pclose|endif
+set completeopt=menuone,menu,longest,preview
+
+colorscheme darkspectrum