civicaml/parser.mly

%{
open Lexing
open Ast

let loc = Util.loc_from_lexpos
%}

/* Tokens */

%token LPAREN RPAREN LBRACK RBRACK LBRACE RBRACE SEMICOL COMMA
%token NOT ADD SUB MUL DIV MOD
%token EQ NE LT LE GT GE
%token AND OR
%token ASSIGN IF ELSE WHILE DO FOR RETURN EXTERN EXPORT
%token INT BOOL FLOAT VOID
%token EOF

%token <bool> BOOL_CONST
%token <float> FLOAT_CONST
%token <int> INT_CONST
%token <string> ID

/* Precedence */

%right ASSIGN
%left OR
%left AND
%left EQ NE
%left LT LE GT GE
%left ADD SUB
%left MUL DIV MOD
%right NOT NEG CAST

%nonassoc IF
%nonassoc ELSE

/* Start symbol */

%type <Ast.node> program
%start program

%%

basic_type : FLOAT      { Float }
           | INT        { Int }
           | BOOL       { Bool }

program : decl*; EOF
          { Program ($1, loc $startpos $endpos) }

decl : EXTERN; fun_header; SEMICOL
       { let (t, n, p) = $2 in FunDec(t, n, p, loc $startpos $endpos) }
     | boption(EXPORT); fun_header; LBRACE; fun_body; RBRACE
       { let (t, n, p) = $2 in FunDef ($1, t, n, p, Block $4, loc $startpos $endpos) }

     | EXTERN; basic_type; ID; SEMICOL
       { GlobalDec ($2, $3, loc $startpos $endpos) }
     | EXTERN; t=basic_type; LBRACK; d=separated_list(COMMA, ID); RBRACK; n=ID; SEMICOL
       { GlobalDec (ArrayDec (t, d), n, loc $startpos $endpos) }

     | boption(EXPORT); basic_type; ID; SEMICOL
       { GlobalDef ($1, $2, $3, None, loc $startpos $endpos) }
     | boption(EXPORT); basic_type; ID; ASSIGN; expr; SEMICOL
       { GlobalDef ($1, $2, $3, Some $5, loc $startpos $endpos) }

     | e=boption(EXPORT); t=basic_type; LBRACK; d=separated_list(COMMA, expr);
            RBRACK; n=ID; SEMICOL
       { GlobalDef (e, ArrayDef (t, d), n, None, loc $startpos $endpos) }
     | e=boption(EXPORT); t=basic_type; LBRACK; d=separated_list(COMMA, expr);
            RBRACK; n=ID; ASSIGN; v=expr; SEMICOL
       { GlobalDef (e, ArrayDef (t, d), n, Some v, loc $startpos $endpos) }

fun_header : ret=basic_type; name=ID; LPAREN; params=separated_list(COMMA, param); RPAREN
             { (ret, name, params) }
           | VOID; name=ID; LPAREN; params=separated_list(COMMA, param); RPAREN
             { (Void, name, params) }

param : basic_type; ID  { Param ($1, $2, loc $startpos $endpos) }

fun_body : var_dec* local_fun_dec* statement* loption(return_statement)
           { $1 @ $2 @ $3 @ $4 }

local_fun_dec : fun_header; LBRACE; fun_body; RBRACE
                { let (t, n, p) = $1 in FunDef (false, t, n, p, Block $3, loc $startpos $endpos) }

var_dec : basic_type; ID; SEMICOL
          { VarDec ($1, $2, None, loc $startpos $endpos) }
        | basic_type; ID; ASSIGN; expr; SEMICOL
          { VarDec ($1, $2, Some $4, loc $startpos $endpos) }
        | t=basic_type; LBRACK; d=separated_list(COMMA, expr); RBRACK; n=ID; SEMICOL
          { VarDec (ArrayDef (t, d), n, None, loc $startpos $endpos) }
        | t=basic_type; LBRACK; d=separated_list(COMMA, expr); RBRACK; n=ID; ASSIGN; v=expr; SEMICOL
          { VarDec (ArrayDef (t, d), n, Some v, loc $startpos $endpos) }

statement : ID; ASSIGN; expr; SEMICOL
            { Assign ($1, $3, loc $startpos $endpos) }
          | name=ID; LPAREN; params=separated_list(COMMA, expr); RPAREN; SEMICOL
            { Expr (FunCall (name, params, loc $startpos $endpos)) }
          | IF; LPAREN; expr; RPAREN; block
            { If ($3, Block $5, loc $startpos $endpos) }                      %prec IF
          | IF; LPAREN; expr; RPAREN; block; ELSE; block
            { IfElse ($3, Block $5, Block $7, loc $startpos $endpos) }        %prec ELSE
          | WHILE; LPAREN; expr; RPAREN; block
            { While ($3, Block $5, loc $startpos $endpos) }
          | DO; block; WHILE; LPAREN; expr; RPAREN; SEMICOL
            { DoWhile ($5, Block $2, loc $startpos $endpos) }
          | FOR; LPAREN; INT; id=ID; ASSIGN; start=expr; COMMA; stop=expr; RPAREN; body=block
            { For (id, start, stop, IntConst (1, noloc), Block body, loc $startpos $endpos) }
          | FOR; LPAREN; INT; id=ID; ASSIGN; start=expr; COMMA; stop=expr;
                COMMA; step=expr; RPAREN; body=block
            { For (id, start, stop, step, Block body, loc $startpos $endpos) }

return_statement : RETURN; expr; SEMICOL  { [Return ($2, loc $startpos $endpos)] }

block : LBRACE; statement*; RBRACE  { $2 }
      | statement                   { [$1] }

expr : LPAREN; expr; RPAREN                 { $2 }
     | name=ID; LPAREN; params=separated_list(COMMA, expr); RPAREN
       { FunCall (name, params, loc $startpos $endpos) }
     | ID                                { Var ($1, loc $startpos $endpos) }
     | l=expr; op=binop; r=expr          { Binop (op, l, r, loc $startpos $endpos) }
     | SUB; expr                         { Monop (Neg, $2, loc $startpos $endpos) }    %prec NEG
     | NOT; expr                         { Monop (Not, $2, loc $startpos $endpos) }
     | LPAREN; basic_type; RPAREN; expr  { TypeCast ($2, $4, loc $startpos $endpos) }  %prec CAST
     | FLOAT_CONST                       { FloatConst ($1, loc $startpos $endpos) }
     | INT_CONST                         { IntConst ($1, loc $startpos $endpos) }
     | BOOL_CONST                        { BoolConst ($1, loc $startpos $endpos) }
     | ID; array_const                   { Deref ($1, $2, loc $startpos $endpos) }
     | array_const                       { ArrayConst ($1, loc $startpos $endpos) }

array_const : LBRACK; values=separated_list(COMMA, expr); RBRACK  { values }

%inline binop : ADD { Add }
              | SUB { Sub }
              | MUL { Mul }
              | DIV { Div }
              | MOD { Mod }
              | EQ  { Eq  }
              | NE  { Ne  }
              | LT  { Lt  }
              | LE  { Le  }
              | GT  { Gt  }
              | GE  { Ge  }
              | AND { And }
              | OR  { Or  }

%%